Referring to Packages Indirectly (Perl Cookbook, 2nd Edition)

## 12.16. Referring to Packages Indirectly

### 12.16.1. Problem

You want to refer to a variable or function in a package unknown until runtime, but syntax like `$packname::$varname` is illegal.

### 12.16.2. Solution

Use symbolic references:

>     {
>         no strict "refs";
>         $val  = ${ $packname . "::" . $varname };
>         @vals = @{ $packname . "::" . $aryname };
>         &{ $packname . "::" . $funcname }("args");
>         ($packname . "::" . $funcname) -> ("args");
>     }

### 12.16.3. Discussion

A package declaration has meaning at compile time. If you don't know the name of the package or variable until runtime, you'll have to resort to symbolic references for direct access to the package symbol table. Assuming you normally run with `use` `strict` in effect, you must disable part of it to use symbolic references. Once you've used the `no` `strict` "`refs`" directive in that block, build up a string with the fully qualified name of the variable or function you're interested in. Then dereference this name as though it were a proper Perl reference.

During the prehistoric eras (before Perl 5), programmers were forced to use an `eval` for this kind of thing:

>     eval "package $packname; \$'$val = \$$varname"; # set $main'val
>     die if $@;

As you see, this approach makes quoting difficult. It's also comparatively slow. Fortunately, you never need to do this just to access variables indirectly by name. Symbolic references are a necessary compromise.

Similarly, `eval` could be used to define functions on the fly. Suppose you wanted to be able to get the base 2 or base 10 logs of numbers:

>     printf "log2  of 100 is %.2f\n", log2(100);
>     printf "log10 of 100 is %.2f\n", log10(100);

Perl has only the natural log function. Here's how one could use `eval` to create these functions at runtime. Here we'll create functions named `log2` up through `log999`:

>     $packname = "main";
>     for ($i = 2; $i < 1000; $i++) {
>         $logN = log($i);
>         eval "sub ${packname}::log$i { log(shift) / $logN }";
>         die if $@;
>     }

Here, at least, you don't need to do that. The following code does the same thing, but instead of compiling a new function 998 times, we compile it only once, as a closure. Then we use symbolic dereferencing of the symbol table to assign the same subroutine reference to many function names:

>     $packname = "main";
>     for ($i = 2; $i < 1000; $i++) {
>         my $logN = log($i);
>         no strict "refs";
>         *{"${packname}::log$i"} = sub { log(shift) / $logN };
>     }

When you assign a reference to a typeglob, you create an alias for just the referent type of that name. That's how the Exporter does its job. The first line in the next code sample manually imports the function name `Colors::blue` into the current package. The second makes the `main::blue` function an alias for the `Colors::azure` function.

>     *blue       = \&Colors::blue;
>     *main::blue = \&Colors::azure;

Given the flexibility of typeglob assignments and symbolic references, a full-blown `eval` "`STRING`" is nearly always unnecessary for these sorts of indirect namespace manipulation, the last resort of the desperate programmer. The only thing worse would be if it weren't available at all.

### 12.16.4. See Also

The section on "Symbolic References" in Chapter 8 of Programming Perl and in the start of perlsub(1); Recipe 11.4

Copyright © 2003 O'Reilly & Associates. All rights reserved.